Задача A. Правильная окраска ≡

Условие

По мотивам романа И.А. Ильфа и Е.П. Петрова "Двенадцать стульев".

Для окраски волос Ипполит Матвеевич Воробьянинов купил в аптеке замечательное средство "Титаник" радикального черного цвета. Возвратившись домой, Ипполит Матвеевич стал поливать голову и усы "Титаником".

После обеда усы обсохли, слиплись, и расчесать их можно было только с большим трудом. Радикальный черный цвет оказался с несколько зеленоватым отливом...

Проснувшись на другой день, Ипполит Матвеевич стал умываться. Но, посмотрев в зеркало, он обнаружил, что его усы и волосы были зелёного цвета.

Его компаньон Остап Бендер купил в аптеке другую микстуру "Наяда". Но после перекраски оказалось, что, смешавшись с зеленью "Титаника", это средство неожиданно окрасило голову и усы Ипполита Матвеевича в краски солнечного спектра. После скептического осмотра Остап предложил Воробьянинову сбрить усы и волосы.

Всё могло бы быть иначе, если бы концессионеры точно рассчитали цвет второго флакона. Посмотрим, как можно это сделать.

Наряду с аддитивной цветовой моделью RGB, используемой для кодирования цветов пикселей экрана, существует и субтрактивная модель RYB, которая применяется для представления цвета в изобразительном искусстве. Для задания цвета в этой модели нужно указать количество красного, желтого и синего цвета как число от 0 до 1. Так, 100 — это красный цвет, 001 — синий, 111 — чёрный, а 110 — оранжевый.

Модель RYB позволяет легко найти цвет смеси двух красок. При смешивании цветов (r₁, y₁, b₁) и (r₂, y₂, b₂) получается цвет (r₃, y₃, b₃), где r₃ = (r₁ + r₂) / k, y₃ = (y₁ + y₂) / k, b₃ = (b₁ + b₂) / k. Здесь k = max{r₁ + r₂, y₁ + y₂, b₁ + b₂}.

Даны цвета (r₁, y₁, b₁) и (r₃, y₃, b₃). С каким цветом (r₂, y₂, b₂) нужно смешать первый цвет, чтобы получить третий цвет?

Формат входного файла

Первая строка входного файла содержит вещественные числа r₁ y₁ b₁. Вторая строка содержит вещественные числа r₃ y₃ b₃.

Хотя бы одно из чисел в каждой тройке равно 1.

Во входных данных не более 2-х знаков после запятой.

Формат выходного файла

Требуется вывести в выходной файл вещественные числа r₂ y₂ b₂ с точностью не менее 5 знаков после запятой.

Все числа должны быть в диапазоне от 0 до 1, и хотя бы одно из чисел должно быть равно 1.

Ограничения

0 ≤ r₁, y₁, b₁, r₃, y₃, b₃ ≤ 1

Гарантируется, что для заданных исходных данных задача имеет решение.

Примеры тестов

1 0 0
1 1 0

0.00000 1.00000 0.00000 

1 0.5 0
1 1 0

0.50000 1.00000 0.00000 

0.25 1 0.5
0.5 0.75 1

0.50000 0.12500 1.00000 

Разбор

Предположим, что r₂ = 1. Тогда из соотношения r₃ = (r₁ + r₂) / k найдём k = r₁ + 1r₃, и тогда найдём остальные числа тройки: r₂ = 1, y₂ = r₁ + 1r₃y₃ − y₁, b₂ = r₁ + 1r₃b₃ − b₁.

Далее нужно проверить, что 0 ≤ y₂, b₂ ≤ 1. Если это не так, то положим y₂ = 1 и повторим аналогичную процедуру. Если мы опять не получили решение, то положим b₂ = 1.

Докажем единственность решения. Предположим, что, когда мы положили r₂ = 1 и y₂ = 1, в обоих случаях выполняется неравенство 0 ≤ r₂, y₂, b₂ ≤ 1. Это означает, что r₁ + 1r₃y₃ − y₁ ≤ 1 и y₁ + 1y₃r₃ − r₁ ≤ 1. Отсюда (r₁ + 1)y₃ ≤ (y₁ + 1)r₃ и (y₁ + 1)r₃ ≤ (r₁ + 1)y₃, поэтому (r₁ + 1)y₃ = (y₁ + 1)r₃. Следовательно, в обоих случаях r₂ = y₂ = 1, поэтому оба случая тождественны.

Пример решения:

var
  c1, c2, c3: array[1..3] of extended;
  k: extended;
  i, j: integer;
  ok: boolean;
begin
  assign(input, 'input.txt');
  reset(input);
  assign(output, 'output.txt');
  rewrite(output);

  ok := false;
  for i := 1 to 3 do
    read(c1[i]);
  for i := 1 to 3 do
    read(c3[i]);

  for i := 1 to 3 do
  begin
    if (c3[i] > 0) then
    begin
      c2[i] := 1;
      k := (c1[i] + 1)/c3[i];
      ok := true;
      for j := 1 to 3 do
      begin
        if (j <> i) then
        begin
          c2[j] := k*c3[j] - c1[j];
          if not ((c2[j] >= -1e-10) and (c2[j] <= 1+1e-10)) then
            ok := false;
        end;
      end;
      if ok then
        break;
    end;
  end;

  for i := 1 to 3 do
    write(c2[i]:0:5, ' ');

  close(input);
  close(output);
end.